Excel CHOOSE функция

Описание

Синтаксис и аргументи

Използване и примери

• Пример 1 - Основна употреба: използване CHOOSE функция само за избор на стойност от списък аргумент
• Ex2 – Връща различни резултати въз основа на множество условия
• Ex3 – Връща различни изчислени резултати въз основа на условия
• Ex4 – Изберете произволно от списъка
• Ex5 – Комбинирайте CHOOSE намлява VLOOKUP функции за връщане на стойност в лявата колона
• Ex6 – Връща ден от седмицата или месец въз основа на дадена дата
• Пример 7 – Връщане към следващия работен ден/уикенд дата въз основа на днес

Описание

- CHOOSE функцията връща стойност от списъка със стойностен аргумент въз основа на дадения индексен номер. Например, CHOOSE(3,”Apple”,”Peach”,”Orange”) връща Orange, индексният номер е 3, а Orange е третата стойност след индексния номер във функцията.

синтаксис и аргументи

Синтаксис на формулата

Аргументи

Value1, value2… могат да бъдат числа, текстове, формули, препратки към клетки или дефинирано име.

Връщана стойност

- CHOOSE функцията връща стойност от списък въз основа на дадената позиция.

Използване и примери

В тази част изброявам някои прости, но представителни примери, за да обясня използването на CHOOSE функция.

Пример 1 - Основна употреба: използване CHOOSE функция само за избор на стойност от списък аргумент

Формула 1:

=CHOOSE(3,"a","b","c","d")

Връщане: c, което е третият аргумент след index_num от 3 в CHOOSE функция.

Забележка: използвайте двойни кавички около стойността, ако е текст.

Формула 2:

=CHOOSE(2,A1,A2,A3,A4)

Връщане: Кейт, стойността на A2. Тъй като index_num е 2, а A2 е втората стойност в CHOOSE функция.

Формула 3:

=CHOOSE(4,8,9,7,6)

Връщане: 6, четвъртият аргумент от списъка във функцията.

Ex2 – Връща различни резултати въз основа на множество условия

Да предположим, че имате списък с отклонения за всеки продукт, които трябва да бъдат етикетирани въз основа на условия, както е показано на екранната снимка по-долу.

Обикновено можете да използвате функцията IF за обработка, но тук ви представям как да използвате CHOOSE функция за лесно решаване на този проблем

Формула:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

Обяснете:

(B7>0)+(B7>1)+(B7>5): index_num, B7 е 2, което е по-голямо от 0 и 1, но по-малко от 5, така че получаваме междинния резултат:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

Както знаем, True = 1, False = 0, така че формулата може да се разглежда като:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

след това

=CHOOSE(2,"Top","Middle","Bottom")

Резултат: Средно

Ex3 – Връща различни изчислени резултати въз основа на условия

Да предположим, че трябва да изчислите отстъпките за всеки продукт въз основа на сумата и цената, както е показано на екранната снимка по-долу:

Формула:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

Обяснете:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 е 102, което е по-голямо от 100, но по-малко от 201, така че в тази част връща резултат, показан като:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

след това

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: стойностите, от които да избирате, отстъпката е равна на цена * сума * процент на отстъпка, тъй като тук index_num е 2, той избира B8*C8*0.2

Връща: 102*2*0.2=40.8

Ex4 – Изберете произволно от списъка

В Excel понякога може да се наложи произволно да изберете стойност от даден списък, the CHOOSE функция може да реши тази задача.

Произволно изберете една стойност от списък:

Формула:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

Обяснете:

RANDBETWEEN(1,5): index_num, произволно получаване на число между 1 и 5

$D$2,$D$3,$D$4,$D$5,$D$6: списък със стойности, от които да избирате

Ex5 – Комбинирайте CHOOSE намлява VLOOKUP функции за връщане на стойност в лявата колона

Обикновено използваме функцията VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) за връщане на стойност въз основа на дадена стойност от диапазон от таблица. Но с VLOOKUP функция, тя ще върне стойност за грешка, докато колоната за връщане е отляво на колоната за справка, както е показано на екранната снимка по-долу:

В този случай можете да комбинирате CHOOSE функция с функция VLOOKUP за решаване на проблема.

Формула:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

Обяснете:

CHOOSE({1,2},B1:B7,A1:A7): като аргумент table_range във функцията VLOOKUP. {1,2} означава да се покаже 1 или 2 като аргумент index_num въз основа на аргумента col_num във функцията VLOOKUP. Тук col_num във функцията VLOOKUP е 2, така че CHOOSE функция дисплей като CHOOSE(2, B1:B7,A1:A7), означава да изберете стойност от A1:A7.

Ex6 – Връща ден от седмицата или месец въз основа на дадена дата

С CHOOSE можете също така да върнете относителния ден от седмицата и месеца въз основа на дадена дата.

Формула 1: връщане на ден от седмицата по дата

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

Обяснете:

WEEKDAY(): аргументът index_num, за да получите номера на деня от седмицата на дадената дата, например WEEKDAY(A5) връща 6, тогава аргументът index_num е 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": аргументи от списъка със стойности, започват с „неделя“, тъй като делничният ден номер „1“ показва „неделя“.

Формула 2: връщане на месеца по дата

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Обяснете:

MONTH(): аргумент index_num, който получава номера на месеца от дадената дата, например MONTH(A5) връща 3.

Пример 7 – Връщане към следващия работен ден/уикенд дата въз основа на днес

В ежедневната работа може да искате да изчислите следващия работен ден или уикенд въз основа на днешния ден. Тук CHOOSE функция също може да ви направи услуга.

Например, днес е 12 г., четвъртък, сега трябва да получите следващия работен ден и уикенда.

Формула 1: вземете днешната дата

=TODAY()

Резултат: 12г

Формула 2: вземете номера на деня от седмицата днес

=WEEKDAY(TODAY())

Резултат: 5 (докато днес е 12)

Списъкът с номера на дните от седмицата, както е показано на екранната снимка по-долу:

Формула 3: вземете на следващия работен ден

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Обяснете:

Today(): върне текущата дата

WEEKDAY(TODAY()): аргумент index_num в CHOOSE функция, вземете номера на днешния ден от седмицата, например неделя е 1, понеделник е 2...

1,1,1,1,1,3,2: аргумент на списък със стойности в CHOOSE функция. Например, ако делничен ден(днес()) върне 1 (неделя), той избира 1 от списъка със стойности, след което цялата формула се променя на =Днес()+1, което означава да добавите 1 ден за връщане следващия понеделник. Ако weekday(today()) върне 6 (петък), той избира 3 от списъка със стойности, тъй като петък е 3 дни далеч от следващия понеделник.

Резултат (докато днес е 12):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

=12+20

=12 г

Формула 4: вземете следващия уикенд ден

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

Обяснете:

6,5,4,3,2,1,1: аргумент на списък със стойности в CHOOSE функция. Например, ако делничен ден(днес()) върне 1 (неделя), той избира 6 от списъка със стойности, тогава цялата формула се променя на =Днес()+6, което означава да добавите 6 дни и да върнете следващата събота.

Резултат:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

=12+20

=12 г

Примерен файл