Как да получа списък с папки в Outlook?

Автор: Силувия Последна промяна: 2014-09-26

Понякога дървовидната структура на всички пощенски папки (включително създадените лични папки) в навигационния панел може да помогне малко на потребителите на Outlook по време на тяхната работа. За бързо изброяване на папките с цялата дървовидна структура кодът VBA може да ви помогне. В този урок можете да научите как лесно да получите списък с папки с VBA код.

Вземете списък с папки в Outlook с VBA код

Раздел Office - Активирайте редактиране и сърфиране с раздели в Microsoft Office, правейки работата лесна

Прочети повече ...Изтегляне на ...

Kutools за Outlook - Увеличете Outlook със 100+ разширени функции за превъзходна ефективност

Автоматизирайте изпращането на имейл с Автоматично CC/BCC, Автоматично препращане по правила; изпрати Автоматичен отговор (Извън офиса) без да е необходим сървър за обмен...
Получавайте напомняния като BCC Предупреждение когато отговаряте на всички, докато сте в списъка BCC, и Напомняне при липсващи прикачени файлове за забравени прикачени файлове...
Подобрете ефективността на имейл с Отговор (на всички) с прикачени файлове, Автоматично добавяне на поздрав или дата и час в подпис или тема, Отговорете на няколко имейла...
Опростете изпращането на имейл с Извикване на имейли, Инструменти за прикачване (Компресиране на всички, автоматично запазване на всички...), Премахване на дубликати, и Бърз доклад...

Увеличете своя Outlook 2021 - 2010 или Outlook 365 с тези разширени функции. Насладете се на цялостен 60-дневен безплатен пробен период и подобрете изживяването си с имейл!

Прочети повече ...Изтегляне на ...

Вземете списък с папки в Outlook с VBA код

За да получите списък с папки в Outlook с VBA код, моля, направете следното.

1. Натисни Друг + F11 клавиши на клавиатурата, за да отворите Microsoft Visual Basic за приложения прозорец.

2. След това щракнете двукратно върху Project1 > Обект на Microsoft Outlook > ThisOutlookSession за да отворите Проект1 – ThisOutlookSession прозорец. Вижте екранна снимка:

3. След това копирайте и поставете VBA кода по-долу в прозореца Project1 – ThisOutlookSession.

VBA: вземете списък с папки в Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. Натисни F5 клавиш на клавиатурата, за да стартирате изпълнението на VBA кода.

5. Сега a Макро изскача диалогов прозорец, моля щракнете върху бягане бутон.

6. Изчакайте стартирането на макроса. След това списъкът с всички ваши имейл папки се извежда незабавно в създаден прозорец за ново съобщение. Можете лесно да го разпечатате. Вижте екранна снимка: