Как да изпратите календар до множество получатели поотделно в Outlook?

Автор: Xiaoyang Последна промяна: 2018-12-14

Обикновено можете да изпратите календар до получател бързо и лесно, като използвате Имейл календар функция в Outlook. Ако искате да изпратите календар, прикачен като iCalendar файл, до множество контакти поотделно, трябва да го изпратите един по един. В тази статия ще говоря за лесен начин за изпращане на календар до множество получатели поотделно в Outlook.

Изпратете календар до множество получатели поотделно с VBA код

Изпратете календар до множество получатели поотделно с VBA код

За да изпратите календар до множество получатели поотделно, следният VBA код може да ви помогне, моля, направете следното:

1. Придвижете се до Контакти и изберете контактите, на които искате да изпратите календара.

2. След това задръжте натиснат ALT + F11 за да отворите Microsoft Visual Basic за приложения прозорец.

3. Щракнете Поставете > Модули, копирайте и поставете кода по-долу в отворения празен модул, вижте екранната снимка:

VBA код: Изпратете календар до множество получатели поотделно:

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. След като въведете кода, натиснете F5 ключ за изпълнение на този код и a Изберете папка изскача диалогов прозорец, моля, изберете календар, който искате да изпратите, вижте екранна снимка:

5. Кликнете OKи след това посочете периода от време, който искате да изпратите на календара в следните полета за подкана, вижте екранната снимка:

6. И след това щракнете OK, нови имейли с прикачен календар са създадени, както е показано на следната екранна снимка, тогава просто трябва да ги изпратите един по един.