Как да маркирам непрочетени имейли, по-стари от определени дни, като прочетени автоматично в Outlook?

Автор: Xiaoyang Последна промяна: 2018-04-10

Ако има няколко непрочетени имейла във вашата папка "Входящи", обикновено можете да приложите функцията Маркиране на всички като прочетени, за да маркирате всички непрочетени имейли като прочетени ръчно. Но опитвали ли сте някога да маркирате непрочетени имейли, които са по-стари от определени дни, като прочетени автоматично в Outlook, без да го настройвате ръчно всеки път?

Маркирайте непрочетените имейли, по-стари от определени дни, като прочетени автоматично с VBA код

Маркирайте непрочетените имейли, по-стари от определени дни, като прочетени автоматично с VBA код

За да маркирате автоматично всички непрочетени имейли, по-стари от определени дни, като прочетени, следният VBA код може да ви направи услуга:

1. Задръжте натиснат ALT + F11 за да отворите Microsoft Visual Basic за приложения прозорец.

2. В Microsoft Visual Basic за приложения прозорец, щракнете два пъти ThisOutlookSession от Проект1(VbaProject.OTM) прозорец, за да отворите режима, и след това копирайте и поставете кода по-долу в празния модул.

VBA код: Автоматично маркиране на непрочетени имейли, по-стари от определени дни, като прочетени:

Private Sub Application_Startup()
        Call MarkOldUnreadEmailsAsRead
    End Sub
    Private Sub MarkOldUnreadEmailsAsRead()
    Dim xInboxFld As Outlook.Folder
    Dim xAccount As Account
    On Error GoTo L1
    For Each xAccount In Outlook.Application.Session.Accounts
        Set xInboxFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderInbox)
        Call Processfolders(xInboxFld)
    Next xAccount
L1:     Exit Sub
    End Sub
    Private Sub Processfolders(ByVal InboxFld As Outlook.Folder)
    Dim xItems As Outlook.Items
    Dim i As Long
    Dim xSubFld As Outlook.Folder
    On Error Resume Next
    Set xItems = InboxFld.Items
    For i = 1 To xItems.Count
        If DateDiff("d", xItems(i).ReceivedTime, Now) >= 15 Then
           If xItems(i).UnRead = True Then
              xItems(i).UnRead = False
              xItems(i).Save
           End If
        End If
    Next
    If InboxFld.Folders.Count > 0 Then
       For Each xSubFld In InboxFld.Folders
           Call Processfolders(xSubFld)
       Next
    End If
End Sub

Забележка: В горния код можете да промените броя на дните в този скрипт: Ако DateDiff("d", xItems(i).ReceivedTime, Now) >= 15 След това според вашите собствени нужди.

3. След това запазете и затворете този прозорец с код, оттогава всеки път, когато стартирате Outlook, всички непрочетени имейли, които са по-стари от предварително зададените дни, ще бъдат автоматично маркирани като прочетени наведнъж.

Забележка: Този код е достъпен само за акаунта за данни по подразбиране.