Как да експортирате имейл адреси въз основа на конкретен домейн в Outlook?

Автор: Xiaoyang Последна промяна: 2022-10-19

Ако искате да експортирате имейл адресите с конкретен домейн от всички контакти във вашия Outlook, моля, прочетете този урок, който ще ви помогне да приложите VBA код за извличане на всички имейл адреси в конкретен домейн в текстов файл, както е показано на екранната снимка по-долу .

Експортирайте имейл адреси въз основа на конкретен домейн в Outlook с VBA код

За да извлечете всички имейл адреси с определен домейн от всички контакти, моля, изпълнете следните стъпки:

1. Създайте нов текстов файл и му дайте име, вижте екранната снимка:

2. Задръжте натиснат ALT + F11 за да отворите Microsoft Visual Basic за приложения прозорец.

3, След това кликнете върху Поставете > Модулии поставете следния код в прозореца на модула.

VBA код: Експортирайте имейл адреси въз основа на конкретен домейн

Dim GDomain As String
Dim GFileSystem As Object
Dim GFilePath As String
Dim GFileObj As Object
Private Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, _
  ByVal ipOperation As String, ByVal lpFile As String, _
  ByVal lpParameters As String, ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long

Sub ExportListOfEmailAddressesInSpecificDomain()
'Updateby ExtendOffice
Dim xStore As Store
Dim xFolder As Folder
On Error Resume Next
GDomain = InputBox("Enter domain(@***.com):", "Kutools for Outlook")
If Len(GDomain) <> 0 Then
  GFilePath = "C:\Users\skyyang\Desktop\Email Addresses with specific domain.txt" 'Specify the file path
  Set GFileSystem = CreateObject("Scripting.FileSystemObject")
  Set GFileObj = GFileSystem.CreateTextFile(GFilePath, True)
  For Each xStore In Application.Session.Stores
    For Each xFolder In xStore.GetRootFolder.Folders
      If xFolder.DefaultItemType = olContactItem Then
        Call ProcessFolders(xFolder)
      End If
    Next
  Next
  GFileObj.Close
  ShellExecute 0&, vbNullString, GFilePath, vbNullString, vbNullString, 1
End If
End Sub

Sub ProcessFolders(ByVal Fld As Outlook.Folder)
Dim xContactItems As Items
Dim I As Long
Dim xContact As ContactItem
Dim xSubFolder As Folder
On Error Resume Next
Set xContactItems = Fld.Items
For I = xContactItems.Count To 1 Step -1
  If xContactItems(I).Class = olContact Then
    Set xContact = xContactItems(I)
    If InStr(xContact.Email1Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email1Address & vbCrLf)
    ElseIf InStr(xContact.Email2Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email2Address & vbCrLf)
    ElseIf InStr(xContact.Email3Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email3Address & vbCrLf)
    End If
  End If
Next
If Fld.Folders.Count > 0 Then
  For Each xSubFolder In Fld.Folders
    If xSubFolder.DefaultItemType = olContactItem Then
      Call ProcessFolders(xSubFolder)
    End If
  Next
End If
End Sub

Забележка: В горния код променете пътя на файла "C:\Users\skyyang\Desktop\Email адреси с конкретен домейн.txt" към своите.

4. И след това натиснете F5 ключ за изпълнение на този код. Изскача поле за подкана, моля, въведете имейл домейна, въз основа на който искате да експортирате имейл адресите, вижте екранната снимка: