Как да получа имейл адреса на подателя от един или повече имейли в Outlook?

Автор: Силувия Последна промяна: 2022-07-20

Опитвали ли сте някога да извлечете имейл адреса от полето „От“ на един или повече получени имейла в Outlook? Тази статия предоставя VBA код, който да ви помогне да се справите с тази задача.

Вземете имейл адреса на подателя от един или повече имейли в Outlook

Моля, стартирайте следния VBA код, за да извлечете имейл адреса от полето „От“ на един или повече получени имейли в Outlook.

1. Отворете имейл папка, изберете имейл съобщение, от което искате да получите имейл адреса на подателя. Натисни Друг + F11 за да отворите Microsoft Visual Basic за приложения прозорец.

Съвети: За да изберете няколко имейла, моля, задръжте натиснат Ctrl и след това изберете имейлите един по един.

2. В Microsoft Visual Basic за приложения прозорец, кликнете Поставете > Модули, след което копирайте следния VBA код в прозореца на модула (код).

VBA код: извлечете имейл адреса на подателя от един или повече имейли в Outlook

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. кликване Инструменти > Препратки, след това проверете Microsoft Scripting Runtime в полето Референции – Проект1 диалогов прозорец.

4. Натисни F5 ключ за изпълнение на кода. Тогава Kutools за Outlook се появява диалогов прозорец, в който са изброени всички имейл адреси на подателя на избраните имейли.

Съвети:

Ако трябва да експортирате списъка с адреси в txt файл, щракнете върху Да бутон.

Или щракнете върху Не бутон за прекратяване на процеса.

5. След като щракнете върху Да бутон, а Преглед за папка изскача диалогов прозорец. Моля, изберете папка за запазване на файла и щракнете върху OK бутон.

6. И накрая, a Kutools за Outlook ще се появи диалогов прозорец, който ви казва пътя на експортирания файл. Кликнете OK да го затворите.

7. Отидете в папката, в която е записан експортираният файл, и отворете .txt файла с име Адрес за да видите имейл адресите на подателя на избраните имейли.