Как да отговоря нормално в папката за изпратени елементи от Outlook?

Автор: Xiaoyang Последна промяна: 2018-11-14

Обикновено, когато щракнете върху функцията за отговор в папката Изпратени за изпращане на друго допълнително съобщение за хората, които сте изпратили, вашият собствен имейл адрес ще се покаже в полето До, както е показано на следната екранна снимка. Това може да е досадно за вас, когато променяте адреса всеки път. Как може Outlook да използва адреса на оригиналния получател, а не вашия?

doc отговор изпратени имейли 1

Отговорете нормално в папката "Изпратени" от Outlook с функцията "Отговори на всички".

Отговорете нормално в папката "Изпратени" от Outlook с VBA код

Отговорете нормално в папката "Изпратени" от Outlook с функцията "Отговори на всички".

В Outlook, Отговори на всички функция може да ви помогне да разрешите този проблем, моля, направете следното:

Когато трябва да отговорите на изпратения имейл за повторно изпращане, за да запазите адреса на оригиналния получател, моля, щракнете Отговори на всички бутон, а адресът на оригиналния получател се намира на Да се поле, както е показано на следната екранна снимка:

doc отговор изпратени имейли 2

Отговорете нормално в папката "Изпратени" от Outlook с VBA код

Понякога може да забравиш Отговори на всички функция, когато отговаряте на изпратеното съобщение, така че кодът на VBA по-долу може да ви помогне да отговорите нормално в папката „Изпратени“, като използвате функцията „Отговор“. Направете със следните стъпки:

1. Задръжте натиснат ALT + F11 за да отворите Microsoft Visual Basic за приложения прозорец.

2. В Microsoft Visual Basic за приложения прозорец, щракнете два пъти ThisOutlookSession от Проект1(VbaProject.OTM) прозорец, за да отворите режима, и след това копирайте и поставете следния код в празния модул.

VBA код: Отговорете нормално в папката Изпратени от Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

doc отговор изпратени имейли 3

3. След това запазете кода и рестартирайте Outlook, за да приемете ефекта на кода сега, когато щракнете Отговор за повторно изпращане на имейл Изпратени елементи папка, адресът на оригиналния получател се показва в полето До, както ви е необходимо.