Как да отпечатате задачи въз основа на категория в Outlook?

Автор: Xiaoyang Последна промяна: 2018-10-22

Да предположим, че има различни цветови категории във вашите задачи в Outlook и сега искате да отпечатате списъците със задачи въз основа на категориите в различни страници. Как бихте могли да решите тази задача в Outlook?

Отпечатайте задачи въз основа на категории в различни страници ръчно една по една

Печат на задачи въз основа на категории в различни страници с VBA код

Отпечатайте задачи въз основа на категории в различни страници ръчно една по една

В Outlook можете ръчно да отпечатате задачите въз основа на различните категории в различни страници една по една, моля, направете следното:

1. Стартирайте Outlook и отидете в прозореца на задачите и изберете папката със задачи, която искате да отпечатате, и след това натиснете Ctrl + E за да активирате Търсене кутия, а след това под Търсене кликнете върху Категоризирани и изберете една цветова категория, която трябва да отпечатате, вижте екранната снимка:

задачи за печат на документи по категория 1

2. И след това всички задачи с конкретната цветова категория са изброени наведнъж, вижте екранната снимка:

задачи за печат на документи по категория 2

3. След това продължете да щраквате досие > Изпринти за да отпечатате този списък със задачи, както е показано на следната екранна снимка:

задачи за печат на документи по категория 3

4. Повторете горните стъпки, за да отпечатате ръчно списъците със задачи с другите цветови категории една по една.

Печат на задачи въз основа на категории в различни страници с VBA код

Ето код на VBA, който може да ви помогне да отпечатате задачите въз основа на категорията в различни страници наведнъж, моля, направете следните стъпки:

1, Отидете на Task прозорец и изберете папката със задачи, която искате да отпечатате.

2. След това задръжте натиснат ALT + F11 за да отворите Microsoft Visual Basic за приложения прозорец.

3. И след това щракнете Поставете > Модули, копирайте и поставете кода по-долу в отворения празен модул:

VBA код: Печат на задачи въз основа на категории в различни страници:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4, След това кликнете Инструменти > Препратки в Microsoft Visual Basic за приложения прозорец, в изскочил Референции-Проект1 диалогов прозорец, проверете Библиотека с обекти на Microsoft Excel намлява Microsoft Scripting Runtime опции от Налични препратки списъчно поле, вижте екранна снимка:

задачи за печат на документи по категория 4

5. И след това щракнете OK бутон, сега, натиснете F5 ключ за изпълнение на този код, след завършване на кода списъците със задачи с различни категории ще бъдат отпечатани на различни страници.