Как автоматично да маркирам имейли въз основа на конкретен прикачен файл в Outlook?

Автор: Xiaoyang Последна промяна: 2018-10-22

Когато получавате някои имейли с конкретен важен прикачен файл, може да се наложи да ги маркирате, така че да можете бързо и лесно да ги намерите за попълване. В тази статия ще говоря за лесен начин за автоматично маркиране на имейли с прикачени файлове с конкретни имена.

Автоматично маркиране на имейли въз основа на конкретен прикачен файл с VBA код

Автоматично маркиране на имейли въз основа на конкретен прикачен файл с VBA код

За да маркирате автоматично имейлите, които съдържат конкретния прикачен файл, моля, приложете следния VBA код:

1. Стартирайте Outlook и след това задръжте ALT + F11 за да отворите Microsoft Visual Basic за приложения прозорец.

2. В Microsoft Visual Basic за приложения прозорец, щракнете два пъти ThisOutlookSession от Проект1(VbaProject.OTM) прозорец, за да отворите нов режим, и след това копирайте и поставете следния код в празния модул.

VBA код: Автоматично маркиране на имейлите въз основа на конкретен прикачен файл:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Забележка: В горния код можете да промените файловото разширение и името на прикачения файл според вашите нужди.

3. След това запазете кода и рестартирайте Outlook, за да влезе кодът в сила, сега, когато получавате имейлите, чиито имена на прикачени файлове съдържат посочения текст, Outlook автоматично ще маркира този имейл за последващи действия, вижте екранната снимка: