Да предположим, че имате списък с имена на служители в рамките на диапазон от работни листове и се стремите да създадете отделни папки за всеки, за да съхранявате тяхната информация. Ръчното създаване на всяка папка може да отнеме много време. Има обаче ефективни методи за ускоряване на този процес. В това ръководство ще споделя няколко подхода за бързо генериране на папки въз основа на посочените стойности на клетките.

Създавайте папки въз основа на стойностите на клетките

• Чрез използване на MD команда и Notepad
• С помощта на мощна функция – Kutools за Excel
• Чрез използване на VBA код

Създавайте папки и подпапки въз основа на стойности на клетки с VBA код

Създавайте папки въз основа на стойностите на клетките

В този раздел ще разгледаме подробно различните методи, предлагайки изчерпателни инструкции стъпка по стъпка за бързо и безпроблемно създаване на папки въз основа на списък със стойности на клетки.

Създайте папки от списък, като използвате командата MD и Notepad

Превръщането на списък от Excel в папки с помощта на командата MD и Notepad е интелигентен трик, който съчетава лесен пакетен скрипт с умението на Excel да поддържа нещата организирани. Този метод е чудесен за бързо създаване на много папки, без да се налага да правите всичко на ръка. Ето ръководство стъпка по стъпка за изпълнение на тази задача:

Стъпка 1: Използвайте командата MD, за да създадете формули

Копирайте или въведете следната формула в празна клетка до стойността на първата ви клетка (например B1) и след това плъзнете манипулатора за попълване надолу, за да приложите формулата към всички елементи от вашия списък.

="MD "&A1

Стъпка 2: Копирайте и поставете формулите във файл на Notepad

1. Натискане Ctrl + C за копиране на клетките с формулата на командата MD.
2. отворено Notepad и натиснете Ctrl + V за да поставите командите в нов файл.
   

Стъпка 3: Запазете файла на Notepad като .bat файл

Кликнете Запази като от досие раздел в Notepad, в Запази като диалогов прозорец, изберете директория, в която искате да създадете множество папки, и след това дайте име на този файл с a . Bat разширение. Накрая щракнете Save бутон. Вижте екранна снимка:

Стъпка 4: Щракнете два пъти върху .bat файла, за да генерирате множество папки

1. Затворете файла Notepad, отидете до папката, в която преди сте запазили .bat файла.
2. Сега станете свидетел на магията: щракнете двукратно върху файла и ще видите множество папки, създадени наведнъж. Вижте демонстрацията по-долу:
   

Създайте папки от списък с помощта на мощен инструмент – Kutools за Excel

С мощните Kutools за ExcelЕ Създаване на папки от съдържанието на клетките функция, сега можете лесно и бързо да създавате папки от списък на Excel. Но това не спира само до основните папки; Kutools също ви позволява да създавате сложни структури с многостепенни подпапки наведнъж. Само няколко прости стъпки могат да преобразуват данните от Excel в организирана система от папки, значително повишавайки продуктивността ви.

След инсталиране Kutools за Excel, Моля, кликнете Kutools плюс > Внос / Износ > Създаване на папки от съдържанието на клетките за да отворите Създаване на папки от съдържанието на клетките диалогов прозорец:

1. Изберете стойностите на клетките, въз основа на които искате да създадете папки;
2. След това кликнете върху бутон за указване на целевата папка, в която искате да запазите папките;
3. Накрая кликнете върху OK бутон.
   

Резултат:

Kutools ще обработи списъка от вашия лист и ще създаде папка за всеки запис в посочената дестинация. Отидете до целевата папка, за да видите резултата. Вижте екранна снимка:

Създавайте папки от списък с помощта на VBA код

Използването на VBA код в Excel може да превърне досадната задача за създаване на папки от списък в бърз, автоматизиран процес. Този раздел ще ви покаже как да приложите VBA код за генериране на папки.

Стъпка 1: Отворете редактора на VBA модул и копирайте кода

1. Задръжте надолу ALT + F11 клавиши в Excel и отваря Microsoft Visual Basic за приложения прозорец.
2. Кликнете Поставете > Модулии поставете следния код в Модули Window.
   VBA код: Създайте папки въз основа на списък със стойности на клетки

   Sub CreateFoldersFromSelection()
   'Updateby Extendoffice
       Dim FolderPath As String
       Dim Cell As Range
       Dim SelectedRange As Range
       Dim FolderName As String
       On Error Resume Next
       Set SelectedRange = Application.InputBox("Select the range with folder names", "Kutools for Excel", Type:=8)
       If SelectedRange Is Nothing Then Exit Sub
       On Error GoTo 0
       
       With Application.FileDialog(msoFileDialogFolderPicker)
           .Title = "Select the destination Folder"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           FolderPath = .SelectedItems(1) & "\"
       End With
       
       For Each Cell In SelectedRange
           FolderName = FolderPath & Cell.Value
           If Cell.Value <> "" And Not FolderExists(FolderName) Then
               MkDir FolderName
           End If
       Next Cell
   End Sub
   
   Function FolderExists(ByVal Path As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(Path) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

Стъпка 2: Изпълнете кода

1. След като поставите този код, моля, натиснете F5 ключ за изпълнение на този код. В полето за подкана изберете стойностите на клетките, от които искате да създадете папки. И след това щракнете OK.
   
2. След това, в следното Изберете целевата папка прозорец, посочете целевия път за извеждане на създадените папки. И след това щракнете OK бутон, вижте екранната снимка:
   

Резултат:

След като изпълните VBA кода, преминете към целевата директория, за да видите резултата. Там ще намерите новосъздадените папки, всяка от които съответства на елемент от вашия списък в Excel. виж екранна снимка:

Създавайте папки и подпапки въз основа на стойности на клетки с VBA код

Понякога може да се окажете в ситуация, в която трябва да генерирате не само папки, но и съответните им подпапки, всички въз основа на данните в клетките на Excel. За да постигна тази задача, тук ще представя код на VBA.

Стъпка 1: Подгответе данните

Първо, трябва да въведете данните, както е показано на следната екранна снимка, да поставите имената на основните папки в първата колона и имената на подпапките във втората колона.

Стъпка 2: Отворете редактора на VBA модул и копирайте кода

1. Задръжте надолу ALT + F11 клавиши в Excel и отваря Microsoft Visual Basic за приложения прозорец.
2. Кликнете Поставете > Модулии поставете следния код в Модули Window.
   VBA код: Създавайте папки и подпапки, базирани на стойности на клетки

   Sub CreateFoldersAndSubfoldersWithUserInput()
   'Updateby Extendoffice
       Dim Rng As Range
       Dim Cell As Range
       Dim basePath As String
       Dim fldrPicker As FileDialog
       Dim FolderPath As String, subfolderPath As String
       On Error Resume Next
       Set Rng = Application.InputBox("Select the range of cells (two columns: one is folder column, another s subfolder column):", "Kutools for Excel", Type:=8)
       If Rng Is Nothing Then Exit Sub
       On Error GoTo 0
       Set fldrPicker = Application.FileDialog(msoFileDialogFolderPicker)
       With fldrPicker
           .Title = "Select the Base Folder Path"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           basePath = .SelectedItems(1)
       End With
       If Right(basePath, 1) <> "\" Then basePath = basePath & "\"
       For Each Cell In Rng.Columns(1).Cells
           If Not Cell.Value = "" Then
               FolderPath = basePath & Cell.Value
               If Not FolderExists(FolderPath) Then MkDir FolderPath
               If Not Cell.Offset(0, 1).Value = "" Then
                   subfolderPath = FolderPath & "\" & Cell.Offset(0, 1).Value
                   If Not FolderExists(subfolderPath) Then MkDir subfolderPath
               End If
           End If
       Next Cell
   End Sub
   
   Function FolderExists(FolderPath As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(FolderPath) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

Стъпка 3: Изпълнете кода

1. След като поставите този код, моля, натиснете F5 ключ за изпълнение на този код. В полето за подкана изберете стойностите на клетките, от които искате да създадете папки. И след това щракнете OK.
   
2. В следващия изскачащ прозорец посочете целевия път за извеждане на създадените папки. И след това щракнете OK бутон, вижте екранната снимка:
   

Резултат:

След като изпълните VBA кода, отидете в целевата директория, за да видите резултата. Ще откриете, че папките и съответните им подпапки, както е продиктувано от стойностите на клетките, са създадени успешно, както е показано на следната екранна снимка:

Свързани членове: