Как да запазите категорията, докато отговаряте или препращате имейл в Outlook?

Автор: Xiaoyang Последна промяна: 2018-11-21

Обикновено, когато отговорите или препратите имейл, който съм категоризирал, категорията ще бъде премахната автоматично от изпратения имейл. Ако искате да запазите категорията на изходящите имейли при отговаряне или препращане, тази статия ще въведе метод за справяне с това.

Запазете категорията, докато отговаряте или препращате имейл с VBA код

Запазете категорията, докато отговаряте или препращате имейл с VBA код

1. Задръжте надолу ALT + F11 за да отворите Microsoft Visual Basic за приложения прозорец.

2. В Microsoft Visual Basic за приложения прозорец, щракнете два пъти ThisOutlookSession от Проект1(VbaProject.OTM) прозорец, за да отворите режима, и след това копирайте и поставете следния код в празния модул.

VBA код: Запазете категорията, докато отговаряте или препращате имейл:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

документ запази категория отговор 1

3. След това запазете и затворете този прозорец с код, затворете и рестартирайте Outlook, сега, когато отговорите или препратите имейл с категория, категорията ще се запази в изходящото съобщение в Изпратени елементи, вижте екранна снимка:

документ запази категория отговор 2